طريقة معرفة سيريال نسخة الويندوز واستخراجه من ويندوز 10 وويندوز 8.1 حتى ويندوز 11، قد ينسى بعض المستخدمين لنظام ويندوز مفاتيح التفعيل للويندوز المثبت على جهازهم، فضياع رخصة الويندوز الذي تم شراءه من قبل يكون شئ محزن، أحيانا قد تضطر إلى استخدام برامج لاستخراج مفتاح الويندوز المثبت على الكمبيوتر، وفي مقالتنا هذه سنتعرف على طريقة استخراج باسورد الويندوز بنفسك من خلال كود بسيط بلغة فيجوال بيسيك اسكريبت، والذي سيسهل علنا استخراج باسورد الويندوز بضغطة واحدة ونسخه داخل ملف مفكرة "نوت باد".
خدعة جميلة في ويندوز 10 استعداد الويندوز للإغلاق بضغطة على سطح المكتب
طريقة معرفة سيريال نسخة الويندوز واستخراجه من ويندوز 10
اصنع بنفسك اسكريبت بسيط يقوم بصيانة الهارد ديسك واصلاح أخطائه وعزل الباد سكتور repair hard disk batch
هذه الطريقة لن تأخد منا أكثر من 10 ثوان في تطبيقها، حيث ستصنع بنفسك سكريبت لمعرفة سيريال الويندوز يفيدك في معرفة تراخيص جميع أنواع الويندوز، بداية ن ويندوز اكس بي مرورا بويندوز 7 و8 و10، وكل ذلك بدون معرفة لغة برمجة، فقط؛ كل ما عليك هو فتح برنامج المفكرة notepad في أي مكان بالجهاز؛ ثم نسخ هذا الكود به
-------------------------------------------------------------------------------------
Option Explicit
Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData & vblf & vblf & "Are you want Save it to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
Save ProductData
End If
'Convert binary to chars
Function ConvertToKey(Key)
Const KeyOffset = 52
Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
'Check if OS is Windows 8
isWin8 = (Key(66) \ 6) And 1
Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
i = 24
Maps = "BCDFGHJKMPQRTVWXY2346789"
Do
Current= 0
j = 14
Do
Current = Current* 256
Current = Key(j + KeyOffset) + Current
Key(j + KeyOffset) = (Current \ 24)
Current=Current Mod 24
j = j -1
Loop While j >= 0
i = i -1
KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
Last = Current
Loop While i >= 0
If (isWin8 = 1) Then
keypart1 = Mid(KeyOutput, 2, Last)
insert = "N"
KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
If Last = 0 Then KeyOutput = insert & KeyOutput
End If
ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
End Function
'Save data to a file
Function Save(Data)
Dim fso, fName, txt,objshell,UserName
Set objshell = CreateObject("wscript.shell")
'Get current user name
UserName = objshell.ExpandEnvironmentStrings("%UserName%")
'Create a text file on desktop
fName = "C:\Users\" & UserName & "\Desktop\Windows Key Info by HD Boot.txt"
Set fso = CreateObject("Scripting.FileSystemObject")
Set txt = fso.CreateTextFile(fName)
txt.Writeline Data
txt.Close
End Function
-------------------------------------------------------------------------------
بعد ذلك قم بحفظ ملف المفكرة بامتداد .vbs
ثم قم بالضغط عليه لفتحه، ستنتج لك هذا BackUp Windows Key Information by HD Boot
لينتج لنا هذا المربع الحواري الذي سظهر لك باسورد الويندوز وحفظه بملف نوت باسم
"Windows Key Info by HD Boot.txt"
BackUp Windows Key Information by HD Boot
سيعجبك الأمر كثيرا.
إذا كنت تريد حفظ سيريال الويندوز داخل نوت باد فعليك بالضغط على زر Yes لترى سيريال الويندوز موجود بملف نوت يمكنك نسخة، أو ستجد الملف موجود على الديسكتوب تحت اسم
"Windows Key Info by HD Boot.txt"
وخلال الأيام المقبلة بإذن الله سنضع لكم برامج لاستعادة جميع السريالات الموجودة بالبرامج في الويندوز.
دمتم بود.
بارك الله فيكم أخي الكريم على هذه المعلومات القيمة. شكرا جزيلا
ردحذفالعفو أخي الكريم، ومرحبا بمرورك
ردحذفإرسال تعليق